SUBROUTINE CGETRSF( TRANS, N, NRHS, A, LDA, IPIV, B, LDB, INFO )

*

*  -- LAPACK routine (version 3.0) --

*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,

*     Courant Institute, Argonne National Lab, and Rice University

*     September 30, 1994

*

*     .. Scalar Arguments ..

      CHARACTER          TRANS

      INTEGER            INFO, LDA, LDB, N, NRHS

*     ..

*     .. Array Arguments ..

      INTEGER            IPIV( * )

      COMPLEX            A( LDA, * ), B( LDB, * )

*     ..

*

*  Purpose

*  =======

*

*  CGETRS solves a system of linear equations

*     A * X = B,  A**T * X = B,  or  A**H * X = B

*  with a general N-by-N matrix A using the LU factorization computed

*  by CGETRF.

*

*  Arguments

*  =========

*

*  TRANS   (input) CHARACTER*1

*          Specifies the form of the system of equations:

*          = 'N':  A * X = B     (No transpose)

*          = 'T':  A**T * X = B  (Transpose)

*          = 'C':  A**H * X = B  (Conjugate transpose)

*

*  N       (input) INTEGER

*          The order of the matrix A.  N >= 0.

*

*  NRHS    (input) INTEGER

*          The number of right hand sides, i.e., the number of columns

*          of the matrix B.  NRHS >= 0.

*

*  A       (input) COMPLEX array, dimension (LDA,N)

*          The factors L and U from the factorization A = P*L*U

*          as computed by CGETRF.

*

*  LDA     (input) INTEGER

*          The leading dimension of the array A.  LDA >= max(1,N).

*

*  IPIV    (input) INTEGER array, dimension (N)

*          The pivot indices from CGETRF; for 1<=i<=N, row i of the

*          matrix was interchanged with row IPIV(i).

*

*  B       (input/output) COMPLEX array, dimension (LDB,NRHS)

*          On entry, the right hand side matrix B.

*          On exit, the solution matrix X.

*

*  LDB     (input) INTEGER

*          The leading dimension of the array B.  LDB >= max(1,N).

*

*  INFO    (output) INTEGER

*          = 0:  successful exit

*          < 0:  if INFO = -i, the i-th argument had an illegal value

*

*  =====================================================================

*

*     .. Parameters ..

      COMPLEX            ONE

      PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )

*     ..

*     .. Local Scalars ..

      LOGICAL            NOTRAN

*     ..

*     .. External Functions ..

      LOGICAL            LSAME

      EXTERNAL           LSAME

*     ..

*     .. External Subroutines ..

      EXTERNAL           CLASWP, CTRSM, XERBLA

*     ..

*     .. Intrinsic Functions ..

      INTRINSIC          MAX

*     ..

*     .. Executable Statements ..

*

*     Test the input parameters.

*

      INFO = 0

      NOTRAN = LSAME( TRANS, 'N' ) .OR. LSAME(TRANS, 'R')

      IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.

     $    LSAME( TRANS, 'C' ) ) THEN

         INFO = -1

      ELSE IF( N.LT.0 ) THEN

         INFO = -2

      ELSE IF( NRHS.LT.0 ) THEN

         INFO = -3

      ELSE IF( LDA.LT.MAX( 1, N ) ) THEN

         INFO = -5

      ELSE IF( LDB.LT.MAX( 1, N ) ) THEN

         INFO = -8

      END IF

      IF( INFO.NE.0 ) THEN

         CALL XERBLA( 'CGETRS', -INFO )

         RETURN

      END IF

*

*     Quick return if possible

*

      IF( N.EQ.0 .OR. NRHS.EQ.0 )

     $   RETURN

*

      IF( NOTRAN ) THEN

*

*        Solve A * X = B.

*

*        Apply row interchanges to the right hand sides.

*

         CALL CLASWP( NRHS, B, LDB, 1, N, IPIV, 1 )

*

*        Solve L*X = B, overwriting B with X.

*

         CALL CTRSM( 'Left', 'Lower', TRANS, 'Unit', N, NRHS,

     $               ONE, A, LDA, B, LDB )

*

*        Solve U*X = B, overwriting B with X.

*

         CALL CTRSM( 'Left', 'Upper', TRANS, 'Non-unit', N,

     $               NRHS, ONE, A, LDA, B, LDB )

      ELSE

*

*        Solve A**T * X = B  or A**H * X = B.

*

*        Solve U'*X = B, overwriting B with X.

*

         CALL CTRSM( 'Left', 'Upper', TRANS, 'Non-unit', N, NRHS, ONE,

     $               A, LDA, B, LDB )

*

*        Solve L'*X = B, overwriting B with X.

*

         CALL CTRSM( 'Left', 'Lower', TRANS, 'Unit', N, NRHS, ONE, A,

     $               LDA, B, LDB )

*

*        Apply row interchanges to the solution vectors.

*

         CALL CLASWP( NRHS, B, LDB, 1, N, IPIV, -1 )

      END IF

*

      RETURN

*

*     End of CGETRS

*

      END